/* 

Rez an SFposer Template anywhere in the region, and add this script in it. This will now be your upgrader box. 

Update the ..SFposer script in the upgrader box with the latest version from the website (https://opensimworld.com/sfposer)

Then go to any SFposer object and click Options->Upgrade  

(Note: the Upgrade option exists only in version 0.90218 and up)
*/

integer channel = -1293191;

default
{
    on_rez(integer n)
    {
        llResetScript();
    }

    state_entry()
    {
        llSetText("SFposer Region Upgrader", <1,1,1>, 1.0);
        llListen(channel, "", "", "SFUPGRADEME");
        llOwnerSay("Click Options->UPGRADE in any SFposer object in the region, and I will upgrade it");
    }
    
    
    listen (integer c, string nm, key id, string m)
    {
        if (llGetOwnerKey(id) != llGetOwner() ) { return; } 
        if (m == "SFUPGRADEME")
        {
            llOwnerSay("Upgrading "+llKey2Name(id)+"...");
            osMessageObject(id, "DO_UPDATE");
        }
    }
    
    dataserver(key id, string m)
    {
        list tok = llParseString2List(m, ["|"], []);
        if (llList2String(tok, 0) ==  "UPDATEPIN")
        {
            key o = llList2Key(tok, 1);
            integer pin = llList2Integer(tok, 2);
            llRemoteLoadScriptPin(o, "..SFposer", pin, TRUE, 99);
        }
    }
    
}